Dynamisch Bezeichner interner Tabellenfelder ausgeben

[Matilda2566]

Hallo zusammen,

ich habe eine selbstdefinierte interne Tabelle. Ich möchte nun nicht nur die Werte der internen Tabelle in eine Datei (z.B. .txt) ausgeben. Sondern ich möchte zuvor als Spaltenüberschrift den Bezeichner (z.B. den Langtext) des jeweiligen Feldes der Struktur als Überschrift vorher ausgeben.

Es gibt doch diese ganzen CL_ABAP*DESCR-Klasssen. Damit müsste es doch gehen? (Ich krieg’s leider nicht gebacken ... )

Könnt Ihr mir vielleicht einen Hinweis oder ein kleines Beispiel geben?

Wenn ich z.B. die Struktur

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. DATA: BEGIN OF wa_tab
2.         ,kunnr  LIKE knvv-kunnr
3.         ,matnr  LIKE mara-matnr
4.    ,maktx  LIKE makt-maktx
5.    ,kbetr  LIKE konp-kbetr
6.         ,END OF wa_tab.
7. DATA: it_tab LIKE TABLE OF wa_tab.
8.  

GeSHi ©

Wie käme ich dann an die hinter den Datenelementen knvv-kunnr, mara-matnr, makt-maktx und konp-kbetr liegenden Langbezeichner?
Ich frage auch deswegen, weil sich die Struktur der internen Tabelle ändern kann. Dies würde dann bei einer kleinen Anpassung in der Struktur keinen weiteren Programmieraufwand bei der Ausgabe bedeuten.

DANKE für Eure Antworten

[Fiona462]

Es gibt doch diese ganzen CL_ABAP*DESCR-Klasssen. Damit müsste es doch gehen? (Ich krieg’s leider nicht gebacken ... )

Könnt Ihr mir vielleicht einen Hinweis oder ein kleines Beispiel geben?

Zeig doch erst einmal Dein Coding, was Du bisher versucht hast.

[Bilal3242]

Wie käme ich dann an die hinter den Datenelementen knvv-kunnr, mara-matnr, makt-maktx und konp-kbetr liegenden Langbezeichner?

Die bekommst du aus Tabelle DD03M, hab's gerade mal getestet:

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. REPORT TESTLA.
2.  
3. TABLES: DD03M.
4.  
5. DATA: LANGTEXT(50).
6.  
7. SELECT * FROM DD03M WHERE TABNAME EQ 'KNVV' AND FIELDNAME EQ 'KUNNR' AND DDLANGUAGE EQ 'DE'.
8.   LANGTEXT = DD03M-SCRTEXT_L.
9. ENDSELECT.
10. WRITE:/ LANGTEXT.
11.  
12. SELECT * FROM DD03M WHERE TABNAME EQ 'MARA' AND FIELDNAME EQ 'MATNR' AND DDLANGUAGE EQ 'DE'.
13.   LANGTEXT = DD03M-SCRTEXT_L.
14. ENDSELECT.
15. WRITE:/ LANGTEXT.
16.  
17. SELECT * FROM DD03M WHERE TABNAME EQ 'MAKT' AND FIELDNAME EQ 'MAKTX' AND DDLANGUAGE EQ 'DE'.
18.   LANGTEXT = DD03M-SCRTEXT_L.
19. ENDSELECT.
20. WRITE:/ LANGTEXT.
21.  
22. SELECT * FROM DD03M WHERE TABNAME EQ 'KONP' AND FIELDNAME EQ 'KBETR' AND DDLANGUAGE EQ 'DE'.
23.   LANGTEXT = DD03M-SCRTEXT_L.
24. ENDSELECT.
25. WRITE:/ LANGTEXT.

GeSHi ©

Du müsstest die Abfrage dann halt nur dynamisch anhand von Variablen machen.

Gruß
Michael

[Salma1291]

Hi,
versuche es mal so:

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. DATA: BEGIN OF wa_tab
2.         ,kunnr  LIKE knvv-kunnr
3.         ,matnr  LIKE mara-matnr
4.    ,maktx  LIKE makt-maktx
5.    ,kbetr  LIKE konp-kbetr
6.         ,END OF wa_tab.
7. DATA: it_tab LIKE TABLE OF wa_tab.
8. ....
9. form test_struct .
10.   DATA  cl_type               TYPE REF TO cl_abap_typedescr.
11.   DATA  cl_struc              TYPE REF TO cl_abap_structdescr.
12.   DATA  cl_elem               TYPE REF TO cl_abap_elemdescr.
13.   FIELD-SYMBOLS <fs_comps>    TYPE abap_compdescr.
14.   DATA  l_type_kind           TYPE abap_typekind.
15.   DATA  l_name                TYPE string.
16.   FIELD-SYMBOLS <fs_any>      TYPE ANY.
17.   DATA wa_dfies               TYPE dfies.
18.  
19. *Prüfung welche Art die Daten sind
20.   l_type_kind =  cl_abap_datadescr=>get_data_type_kind( p_data = wa_tab ).
21.  
22. * Strukturen weiter auflösen
23.   IF l_type_kind CA 'uv'.
24.     cl_struc ?= cl_abap_datadescr=>describe_by_data( p_data = wa_tab  ).
25. * Jedes Element der Struktur prüfen
26.     LOOP AT cl_struc->components ASSIGNING <fs_comps>.
27.       ASSIGN COMPONENT <fs_comps>-name OF STRUCTURE wa_tab TO <fs_any>.
28.       IF sy-subrc EQ 0.
29. * Element -> Element Definition holen
30.           cl_elem ?= cl_abap_datadescr=>describe_by_data( p_data = <fs_any>  ).
31. * Namen des Feldes
32.           l_name = cl_elem->get_relative_name( ).
33. * Hier wird auf DDIC Bezug gepürft:
34.           IF cl_elem->is_ddic_type( ) = 'X'.
35.             TRY.
36. * Hole die Feldinfos aus dem DDIC
37.                 wa_dfies = cl_elem->get_ddic_field( ).
38.                 write : / 'DDIC:',<fs_comps>-name, wa_dfies-SCRTEXT_L.
39.               CATCH cx_root.
40.                 CLEAR wa_dfies.
41.                 write : / 'Fehler DDIC:', <fs_comps>-name, l_name.
42.             ENDTRY.
43.           ELSE.
44. * Kein DDic Bezug -> keine Beschreibung nehme den Namen des Feldes
45.             write : / 'Kein DDIC:', <fs_comps>-name, l_name.
46.           ENDIF.
47.       ENDIF.
48.     ENDLOOP.
49.   endif.
50. endform.                    " test_struct
51.  

GeSHi ©

[Ilja583]

Hallo Lars,

du kannst auch versuchen die Klasse CL_SALV_TABLE das für dich erledigen zu lassen.
Beispiel:

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. REPORT.
2.  
3. TYPES: BEGIN OF ty_test,
4.           matnr TYPE matnr,
5.           werks TYPE werks_d,
6.           datum TYPE sydatum,
7.        END OF ty_test.
8.  
9. DATA: t_data TYPE STANDARD TABLE OF ty_test WITH NON-UNIQUE DEFAULT KEY.
10.  
11. DATA: cl_salv   TYPE REF TO cl_salv_table,
12.       cl_cols   TYPE REF TO cl_salv_columns_table,
13.       t_cols    TYPE salv_t_column_ref,
14.       longtext  TYPE scrtext_l.
15. FIELD-SYMBOLS: <col> LIKE LINE OF t_cols.
16.  
17. START-OF-SELECTION.
18.  
19.   cl_salv_table=>factory( IMPORTING r_salv_table   = cl_salv
20.                           CHANGING  t_table        = t_data ).
21.  
22.   cl_cols = cl_salv->get_columns( )."->get( ).
23.   t_cols  = cl_cols->get( ).
24.   LOOP AT t_cols ASSIGNING <col>.
25.  
26.     longtext = <col>-r_column->get_long_text( ).
27.     WRITE:/ <col>-columnname,
28.             longtext.
29.  
30.   ENDLOOP.

GeSHi ©

[ewx]

Hi Edwin,

ich habe dein Programm noch mal angepasst, da es bei in der Struktur eingebetteten Strukturen zu einem Kurzdump kommt...

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1.  
2. REPORT.
3.  
4. TYPES: BEGIN OF ty_test,
5.          langu TYPE sylangu,
6.          abcde TYPE syabcde,
7.        END OF ty_test.
8.  
9. DATA: BEGIN OF wa_tab
10.         ,kunnr  LIKE knvv-kunnr
11.         ,matnr  LIKE mara-matnr
12.         ,maktx  LIKE makt-maktx
13.         ,kbetr  LIKE konp-kbetr
14.         ,flag   TYPE c LENGTH 10 " Ohne DDIC
15.         ,werks  TYPE werks_d     " Datenelement
16.         ,test   TYPE ty_test        " Struktur!!
17.      ,END OF wa_tab.
18. DATA: it_tab LIKE TABLE OF wa_tab.
19.  
20. *  DATA  cl_elem               TYPE REF TO cl_abap_elemdescr.
21.  
22. PERFORM test_struct.
23.  
24.  
25. *&---------------------------------------------------------------------*
26. *&      Form  struc
27. *&---------------------------------------------------------------------*
28. FORM struc USING value(istruc).
29.  
30.   DATA  cl_type               TYPE REF TO cl_abap_typedescr.
31.   DATA  cl_struc              TYPE REF TO cl_abap_structdescr.
32.   DATA  cl_elem               TYPE REF TO cl_abap_elemdescr.
33.   FIELD-SYMBOLS <fs_comps>    TYPE abap_compdescr.
34.   DATA  l_type_kind           TYPE abap_typekind.
35.   DATA  l_name                TYPE string.
36.   FIELD-SYMBOLS <fs_any>      TYPE ANY.
37.   FIELD-SYMBOLS <fs_any2>     TYPE ANY.
38.   DATA wa_dfies               TYPE dfies.
39.  
40.   cl_struc ?= cl_abap_datadescr=>describe_by_data( p_data = istruc  ).
41. * Jedes Element der Struktur prüfen
42.   LOOP AT cl_struc->components ASSIGNING <fs_comps>.
43.     ASSIGN COMPONENT <fs_comps>-name OF STRUCTURE istruc TO <fs_any>.
44.     IF sy-subrc EQ 0.
45.  
46.       DESCRIBE FIELD <fs_any> TYPE l_type_kind.
47.       IF l_type_kind = 'u'.
48.         PERFORM struc USING <fs_any>.
49.       ELSE.
50.  
51. * Element -> Element Definition holen
52.         cl_elem ?= cl_abap_datadescr=>describe_by_data( p_data = <fs_any>  ).
53. * Namen des Feldes
54.         l_name = cl_elem->get_relative_name( ).
55. * Hier wird auf DDIC Bezug gepürft:
56.         IF cl_elem->is_ddic_type( ) = 'X'.
57.           TRY.
58. * Hole die Feldinfos aus dem DDIC
59.               wa_dfies = cl_elem->get_ddic_field( ).
60.               WRITE : / 'DDIC:',<fs_comps>-name, wa_dfies-scrtext_l.
61.             CATCH cx_root.
62.               CLEAR wa_dfies.
63.               WRITE : / 'Fehler DDIC:', <fs_comps>-name, l_name.
64.           ENDTRY.
65.         ELSE.
66. * Kein DDic Bezug -> keine Beschreibung nehme den Namen des Feldes
67.           WRITE : / 'Kein DDIC:', <fs_comps>-name, l_name.
68.         ENDIF.
69.       ENDIF.
70.     ENDIF.
71.   ENDLOOP.
72.  
73. ENDFORM.                    "struc
74.  
75. *&---------------------------------------------------------------------*
76. *&      Form  test_struct
77. *&---------------------------------------------------------------------*
78. FORM test_struct .
79.  
80.   DATA  l_type_kind           TYPE abap_typekind.
81.  
82. *Prüfung welche Art die Daten sind
83.   l_type_kind =  cl_abap_datadescr=>get_data_type_kind( p_data = wa_tab ).
84.  
85. * Strukturen weiter auflösen
86.   IF l_type_kind CA 'uv'.
87.     PERFORM struc USING wa_tab.
88.   ENDIF.
89. ENDFORM.                    " test_struct
90.  

GeSHi ©

Dabei ist mir was Lustiges aufgefallen:
Probiert mal

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. report.
2. DATA  l_type_kind           TYPE abap_typekind.
3.  

GeSHi ©

Beim Prüfen melder der Compiler: Der Typ ABAP_TYPEKIND" ist unbekannt.

So ist das Coding wieder fehlerfrei:

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. report.
2. DATA  cl_elem               TYPE REF TO cl_abap_elemdescr.
3. DATA  l_type_kind           TYPE abap_typekind.
4.  

GeSHi ©

[Salma1291]

Hi,
das ist ja auch nur ein Beispiel für die Verwendung. Ein bisschen Arbeit wollte ich euch auch noch lassen.

Gruss Edwin

[Salma1291]

Hi Enno,

der Typ ABAP_TYPEKIND ist im Type-Pool Abap definiert.
durch
DATA cl_elem TYPE REF TO cl_abap_elemdescr.
zieht sich der Compiler auch "CL_ABAP_ELEMDESCR" dieser erbt von "CL_ABAP_TYPEDESCR" und in diesem ist der Type-pool ABAP eingebunden.

Nach der Definition :
DATA cl_elem TYPE REF TO cl_abap_elemdescr.
oder auch
DATA cl_type TYPE REF TO cl_abap_typedescr.
können auch die Typen aus dem Type-pool ABAP benutzt werden.

Gruss Edwin

[Matilda2566]

Hallo Leute,

vielen Dank für Eure vielen Antworten

Es freut sich sehr der Kleine Eisbär