ALV Event bei Cursorbewegung

[Hussein2103]

Hallo zusammen,

gibt es eine Methode oder ein Event das ausgelöst wird wenn im ALV-Grid der Cursor in den Zeilen rauf/runter bewegt wird?

[Devran3367]

Leider nein für was brauchst du das ?

[Hussein2103]

Moin,

zu den Sätzen im ALV sollen in einem darunter liegendem Fenster die dazugehörigen Texte (aus Auftrag/Lieferung/Bestellung/...) angezeigt werden. Bisherige Lösung erfordert eine F-Taste. Es wird die automatische Anzeige gewünscht sobald der Cursor die Zeile wechselt.

[Linnea2424]

durch das bewegen des cursors wird kein event gefeuert. für solche fälle (kopfsicht oben und positionssicht unten) erstelle ich in der einzelnen zelle des kopf-alv einen button, der durch betätigen das pos-alv aktualisiert.

[Ilja583]

Hallo Iridium,

solange du im "oberen" Bereich keine Eingabefelder hast, könntest du evtl. etwas probieren wie im folgenden Demoprogramm.
Einfach mal ausprobieren und den Cursor in eine Zeile stellen. Mit 1-2 sekündiger Verzögerung wird dann im unteren Fenster angezeigt auf welcher Zeile der Cursor steht. ( Es ginge auch mit noch kürzeren Abständen (etwa Zehntelsekunden) - aber dann nicht mehr mit dem einfachen Timercontrol )

ACHTUNG - es muss ein Dynpro 9000 angelegt werden mit einem Customcontrol namens "CONTAINER_9000" ( ohne Ablauflogik aber mit Folgescreen 0 )

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. REPORT.
2.  
3.  
4. DATA:   gcl_grid     TYPE REF TO cl_gui_alv_grid,
5.         gcl_text     TYPE REF TO cl_gui_textedit,
6.         gcl_timer    TYPE REF TO cl_gui_timer.
7.  
8. *----------------------------------------------------------------------*
9. *       CLASS lcl_event_receiver DEFINITION
10. *----------------------------------------------------------------------*
11. CLASS lcl_event_receiver DEFINITION.
12.   PUBLIC SECTION.
13.     CLASS-METHODS: handle_timer_tick FOR EVENT finished OF cl_gui_timer.
14. ENDCLASS.                    "lcl_event_receiver DEFINITION
15.  
16. *----------------------------------------------------------------------*
17. *       CLASS lcl_event_receiver IMPLEMENTATION
18. *----------------------------------------------------------------------*
19. CLASS lcl_event_receiver IMPLEMENTATION.
20.   METHOD handle_timer_tick.
21. *    BREAK-POINT.
22.     DATA: row TYPE i,
23.           text_c TYPE text10,
24.           text_s TYPE string.
25. * Get selected row of grid
26.     gcl_grid->get_current_cell(
27.       IMPORTING
28.         e_row     = row ).
29. * Write row to text
30.     WRITE row TO text_c.
31.     CONCATENATE 'Row:' text_c INTO text_s.
32.     gcl_text->set_textstream( text_s ).
33.  
34.     gcl_timer->run( ).  " Restart timer
35.  
36.  
37.   ENDMETHOD.                    "handle_timer_tick
38. ENDCLASS.                    "lcl_event_receiver IMPLEMENTATION
39.  
40.  
41. START-OF-SELECTION.
42.   PERFORM build_objects.
43.  
44.  
45. END-OF-SELECTION.
46.   gcl_timer->run( ).  " Start timer
47.   CALL SCREEN 9000.
48.  
49.  
50. *&---------------------------------------------------------------------*
51. *&      Form  build_objects
52. *&---------------------------------------------------------------------*
53. FORM build_objects.
54.  
55.   DATA: repid TYPE syrepid,
56.         dynnr TYPE sydynnr.
57.   DATA: cl_custom   TYPE REF TO cl_gui_custom_container,
58.         cl_splitter TYPE REF TO cl_gui_easy_splitter_container,
59.  
60.         t_t000 TYPE STANDARD TABLE OF t000 WITH NON-UNIQUE DEFAULT KEY.
61.  
62. * Customcontainer on screen 9000
63.   repid = sy-repid.
64.   dynnr = '9000'.
65.   CREATE OBJECT cl_custom
66.     EXPORTING
67.       container_name = 'CONTAINER_9000'
68.       repid          = repid
69.       dynnr          = dynnr.
70.  
71. * Fill with easy splitter ( 50% - 50% split horizontally )
72.   CREATE OBJECT cl_splitter
73.     EXPORTING
74.       parent = cl_custom.
75.  
76. * Grid in top_container
77.   CREATE OBJECT gcl_grid
78.     EXPORTING
79.       i_parent = cl_splitter->top_left_container.
80. * and fill with some data
81.   SELECT *
82.     INTO TABLE t_t000
83.     FROM t000.
84. * Some more lines
85.     while lines( t_t000 ) < 100.
86.       append LINES OF t_t000 to t_t000.
87.     endwhile.
88.   gcl_grid->set_table_for_first_display(
89.     EXPORTING
90.       i_structure_name              = 'T000'
91.     CHANGING
92.       it_outtab                     = t_t000 ).
93.  
94.  
95. * Text in bottom container
96.   CREATE OBJECT gcl_text
97.     EXPORTING
98.       parent = cl_splitter->bottom_right_container.
99. * no input for this
100.   gcl_text->set_readonly_mode( cl_gui_textedit=>true ).
101.  
102.  
103.  
104. * Timer
105.   CREATE OBJECT gcl_timer.
106. * 1 second delay
107.   gcl_timer->interval = 1.
108. * set handler
109.   SET HANDLER lcl_event_receiver=>handle_timer_tick FOR gcl_timer.
110.  
111.  
112. ENDFORM.                    "build_objects

GeSHi ©

[Ilja583]

Nachtrag - die Tabelle "T_T000" muss doch global definiert werden, sonst kommt es in bestimmten Situationen zu Kurzdumps.