Dynamische Typisierung

[Rudolf1279]

Ich würde gern einen Typ generisch typisieren.

Also so etwa:

Types: begin of ty_alv_gp,
STRNAME type ZBCT_LOGDATA-STRNAME,
COUNTER type ZBCT_LOGDATA-COUNTER.
include type zfi_s_IMP_MS_GP.
Types: end of ty_alv_gp.


Die Struktur "zfi_s_IMP_MS_GP" kann jedoch auch "ZFI_S_IMP_MS_FI" sein. Das weiß ich erst zur Laufzeit.

Habe im Tricktresor schon etwas nettes gefunden:
field-Symbols: <fs_structure> type any.
DATA: dref TYPE REF TO data.

* Dynamische Struktur erzeugen und Zuweisung zum Feldsymbol
CREATE DATA dref TYPE (gv_str).
ASSIGN dref->* TO <fs_structure>.

In der Variable "gv_str" steht meine Struktur. Das klappt auch und ich kann mir das Feldsymbol <fs_structure> ansehen während der Laufzeit. Allerdings kann ich in meinem Typ oben das nicht nutzen zur Typisierung, weder mit "type" noch mit "like". Beides mal kommen Fehlermeldungen.

Irgendeine Idee, wie das funktionieren könnte? Das wäre klasse. Sonst müsste ich viel Coding redundant kopieren, was sehr unschön wäre.

Schönen Gruß, René

[Ilja583]

Beispielreport

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. REPORT.
2.  
3. DATA: dref TYPE REF TO data.
4. FIELD-SYMBOLS: <fs> TYPE ANY.
5.  
6. PARAMETERS: table TYPE tabname OBLIGATORY DEFAULT 't000'.
7.  
8.  
9. **********************************************************************
10. START-OF-SELECTION.
11. * 1. Schritt wie im Tricktresor - Variable mit angegebenem Typ erzeugen
12.   CREATE DATA dref TYPE (table).
13.   ASSIGN dref->* TO <fs>.
14.  
15. * 2. Schritt - Erweitern einer Struktur [hier um einen festen Teil am Ende der Struktur]
16.   PERFORM extend_structure USING    <fs>
17.                            CHANGING dref.
18.   ASSIGN dref->* TO <fs>.
19.  
20.  
21.   BREAK-POINT.
22.  
23.  
24. *&---------------------------------------------------------------------*
25. *&      Form  extend_structure
26. *&---------------------------------------------------------------------*
27. FORM extend_structure  USING    p_structure TYPE any
28.                        CHANGING p_dref      TYPE REF TO data.
29.   DATA: cl_desc1           TYPE REF TO cl_abap_structdescr,
30.         t_component_table1 TYPE cl_abap_structdescr=>component_table,
31.  
32.         cl_desc2           TYPE REF TO cl_abap_structdescr,
33.         t_component_table2 TYPE cl_abap_structdescr=>component_table,
34.  
35.         cl_desc            TYPE REF TO cl_abap_structdescr,
36.         t_component_table  TYPE cl_abap_structdescr=>component_table.
37.  
38.   DATA: BEGIN OF fix_part,
39.           checked TYPE flag,
40.           light   TYPE char1,
41.         END OF fix_part.
42.  
43.   cl_desc1 ?= cl_abap_typedescr=>describe_by_data( p_structure )        .
44.   t_component_table1 = cl_desc1->get_components( ).
45.  
46.   cl_desc2 ?= cl_abap_typedescr=>describe_by_data( fix_part )        .
47.   t_component_table2 = cl_desc2->get_components( ).
48.  
49.   APPEND LINES OF t_component_table1 TO t_component_table.   " Die übergebene Struktur
50.   APPEND LINES OF t_component_table2 TO t_component_table.   " Der feste Teil dahinter
51.   cl_desc = cl_abap_structdescr=>create( t_component_table ).
52.  
53.   CREATE DATA p_dref TYPE HANDLE cl_desc.                    " Ergibt dann eine Gesamtstruktur
54.  
55. ENDFORM.                    "extend_structure

GeSHi ©

[Rudolf1279]

Hallo Stefan,

vielen Dank !! Das werde ich mal ausprobieren. Bin heute beim anderen Kunden, daher kann ich es erst am Dienstag testen.

Aber das sieht schon mal super fuchsig aus.

Vielen Dank und ein schönes Wochenende,

René