SMARTFORMS Seitenzahl bei einer Seite nicht anzeigen.

[Pelin2735]

Hallo,

ich habe das Problem, das ich die Ausgabe der Seitenzahl unterdrücken will, wenn das Dokument nur eine Seite hat. Ich möchte gerne "Seite 1 von 1" nicht anzeigen. Als Bedingung hab ich folgendes für das Textfeld definiert:

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. SFSY-FORMPAGES > 1

GeSHi ©

Auf der 2. Seite zeigt er korrekt die Seitenzahl an, aber bei mehr als einer Seite im Dokument wird die Seitenzahl aufgrund der Bedingung nicht angezeigt.
Wenn ich die Bedingung aber rausnehme, dann wird sfsy-formpages korrekt angezeigt.

[Tron]

Moin.
Ich behaupte mal, dass die Seitenzahlen WÄHREND der Verarbeitung gar nicht zur Verfügung stehen, sondern erst NACHDEM das Formular prozessiert wurde (und somit klar ist, wieviele Seiten es geben wird) in das OTF-Spoolfile eingearbeitet wird.

gruß Jens

[Pelin2735]

Das ist auch meine Vermutung.
Bei dem Allgemeinen Eigenschaften einer Seite kann man ja den Seitenzähler auf den Modus fortlaufend Zählen einstellen.
Wahrscheinlich wird sfsy-formpage bei der Erstellung der Seite wie sfsy-page hochgezählt und nach Erstellung aller Dokumente des Formulars werden alle Vorkommen mit den korrekten Werten ersetzt. Somit hat sfsy-formpages wahrscheinlich in Bedingungen auf der ersten Seite immer den Wert 1, egal wie viele Dokumente/Seiten das Formular hat.

Hat jemand einen Vorschlag wie man das Problem lösen kann?

[Tron]

Ja.
Ich habe eine Lösung, welche darauf basiert:
Einen Platzhalter im Formular Textknoten zu hinterlegen.(e.g. Seite $PAGE / $PAGES)
Das Smartform nicht direkt drucken zu lassen, sondern OTF zurückzugeben.
(dann hat man auch die Gesamtzahl der Seiten)
Anschliessend im OTF-Stream die Seitenzahlen gegen die Platzhalter austauschen und
den OTF Stream zum Drucken bzw. der Vorschau zu übergeben.
Beispiel:

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. *&---------------------------------------------------------------------*
2. *& Report  ZTEST_SF_OTF
3. *&
4. *&---------------------------------------------------------------------*
5. *&
6. *&
7. *&---------------------------------------------------------------------*
8.  
9. REPORT  ztest_sf_otf.
10.  
11. DATA: fm_name TYPE rs38l_fnam,
12.       gv_form TYPE tdsfname VALUE 'ZTEST_PLOT'.
13.  
14. DATA:
15.       ls_document_output_info TYPE ssfcrespd,
16.       ls_control_para TYPE ssfctrlop,
17.       ls_outopt TYPE ssfcompop.
18.  
19. * OTF data
20. DATA:
21.       lt_otf TYPE itcoo OCCURS 0 WITH HEADER LINE,
22.       lt_otf_sf TYPE ssfcrescl,
23.       lv_numbytes TYPE i,
24.       result TYPE ssfpp.
25.  
26. DATA: rc TYPE i.
27. DATA l_pc(3) TYPE c.
28.  
29. FIELD-SYMBOLS <p> TYPE itcoo.
30.  
31. SELECTION-SCREEN BEGIN OF BLOCK a WITH FRAME TITLE text-000.
32. PARAMETERS tclip TYPE c RADIOBUTTON GROUP 3.
33. PARAMETERS fclip TYPE c RADIOBUTTON GROUP 3 DEFAULT 'X'.
34. SELECTION-SCREEN END OF BLOCK a.
35.  
36.  
37. ls_control_para-langu = 'E'.
38. ls_control_para-no_dialog = 'X'.
39. ls_control_para-preview = space.
40. ls_control_para-getotf = 'X'.
41. ls_outopt-tddest = 'LP01'.
42.  
43.  
44. CALL FUNCTION 'SSF_FUNCTION_MODULE_NAME'
45.   EXPORTING
46.     formname           = gv_form
47.   IMPORTING
48.     fm_name            = fm_name
49.   EXCEPTIONS
50.     no_form            = 1
51.     no_function_module = 2
52.     OTHERS             = 3.
53.  
54.  
55. CALL FUNCTION fm_name
56.   EXPORTING
57. *   ARCHIVE_INDEX        =
58. *   ARCHIVE_INDEX_TAB    =
59. *   ARCHIVE_PARAMETERS   =
60.     control_parameters   = ls_control_para
61. *   MAIL_APPL_OBJ        =
62. *   MAIL_RECIPIENT       =
63. *   MAIL_SENDER          =
64.     output_options       = ls_outopt
65.     user_settings        = ' '
66.   IMPORTING
67.     document_output_info = ls_document_output_info
68.     job_output_info      = lt_otf_sf
69. *   JOB_OUTPUT_OPTIONS   =
70.   EXCEPTIONS
71.     formatting_error     = 1
72.     internal_error       = 2
73.     send_error           = 3
74.     user_canceled        = 4
75.     OTHERS               = 5.
76.  
77. IF sy-subrc <> 0.
78.   EXIT.
79. ENDIF.
80.  
81. lt_otf[] = lt_otf_sf-otfdata[].
82.  
83. *in ls_document_output_info-TDFPAGES steht die Seitenzahl
84.  
85.  
86. LOOP AT lt_otf ASSIGNING <p> WHERE
87.    tdprintcom EQ 'ST' AND ( tdprintpar CS '$PAGE' OR tdprintpar CS '$PAGES' )
88.   OR
89.    tdprintcom EQ 'IN' AND tdprintpar(2) EQ '05' .
90.  
91.   IF <p>(4) EQ 'IN05'.
92.     ADD 1 TO l_pc.
93.   ELSE.
94.     REPLACE '$PAGE'  IN <p>-tdprintpar WITH l_pc.
95.     REPLACE '$PAGES' IN <p>-tdprintpar WITH ls_document_output_info-tdfpages.
96.   ENDIF.
97.  
98. ENDLOOP.
99.  
100.  
101.  
102. IF NOT tclip IS INITIAL.
103.   CALL METHOD cl_gui_frontend_services=>clipboard_export
104.     IMPORTING
105.       data                 = lt_otf[]
106.     CHANGING
107.       rc                   = rc
108.     EXCEPTIONS
109.       cntl_error           = 1
110.       error_no_gui         = 2
111.       not_supported_by_gui = 3
112.       OTHERS               = 4.
113.  
114.   IF sy-subrc <> 0.
115.   ENDIF.
116.  
117. ELSE.
118.  
119.   REFRESH lt_otf.
120.   CALL METHOD cl_gui_frontend_services=>clipboard_import
121.     IMPORTING
122.       data                 = lt_otf[]
123. *     length               =
124.     EXCEPTIONS
125.       cntl_error           = 1
126.       error_no_gui         = 2
127.       not_supported_by_gui = 3
128.       OTHERS               = 4.
129.  
130.   IF sy-subrc <> 0.
131.   ENDIF.
132.  
133. ENDIF.
134.  
135. CALL FUNCTION 'SSFDISPLAY_OTF'
136. * EXPORTING
137. *   DISPLAY_PARAMETERS       =
138. *   ARCHIVE_PARAMS           =
139. *   SPOOLATTR                =
140. *   SHOW_DIALOG              = ' '
141. * IMPORTING
142. *   RESULT                   =
143.   TABLES
144.     otf                      = lt_otf[]
145.  EXCEPTIONS
146.    error                    = 1
147.    OTHERS                   = 2.
148.  
149. IF sy-subrc <> 0.
150. ENDIF.
151.  
152.  
153.  
154.  
155. ** ===============OK===========================
156. *
157. *data ls type SSFPP.
158. *ls-TDDEST = ls_outopt-tddest..
159. *ls-TDIMMED = 'X'.
160. *ls-TDDELETE = ' '.
161. *
162. *CALL FUNCTION 'SSFPRINT_OTF'
163. *  EXPORTING
164. *    printoptions           = ls
165. ** IMPORTING
166. **   OTF_PRINTER            =
167. **   OTF_DEVICETYPE         =
168. **   PRINT_SUCCESSFUL       =
169. **   SPOOLID                =
170. *  tables
171. *    otf                    = lt_otf.
172. ** ============================================
173.  
174.  
175. ** ==================OK========================
176. *DATA ls TYPE itcpo.
177. *
178. *ls-tddest = ls_outopt-tddest.
179. *ls-tdimmed  = ' '.
180. *ls-tddelete = ' '.
181. *
182. *
183. *CALL FUNCTION 'PRINT_OTF'
184. *  EXPORTING
185. *    printoptions           = ls
186. ** IMPORTING
187. **   OTF_PRINTER            =
188. **   OTF_DEVICETYPE         =
189. **   PRINT_SUCCESSFUL       =
190. **   SPOOLID                =
191. *  TABLES
192. *    otf                    = lt_otf.
193. ** ============================================
194.  

GeSHi ©

Zu Übungszwecken habe ich eine Clipboard Funktion eingebaut, damit man ein wenig experimentieren und den OTF-Stream in einen Texteditor "pasten" kann.
Die inaktiven Abschnitte enthalten die Übergabe des OTFs an den Spool zum Drucken.

viel Spass beim Experimentieren
lg Jens
siehe auch
http://help.sap.com/saphelp_40b/helpdat ... ontent.htm

[Tron]

... und nochmal zusammen Style plus Form...
und eine bessere Dokumentation(PDF)
https://www.sdn.sap.com/irj/scn/index?r ... ayout=true

[Pelin2735]

Vielen Dank für deine umfangreiche Antwort!

Habe mir jetzt auch noch die Schulungsunterlagen von SmartForms(BC470) geben lassen. Da ist dieses Verfahren bei den Übungsaufgaben zu Kapitel 3 wie folgt beschrieben:

2 Seiten erzeugen, zum Bsp. FIRST und NEXT
Folgeseite von FIRST ist NEXT, und NEXT hat sich selbst als Folgeseite
Die Seitenzahl wird im Fenster PAGE angezeigt, welches nicht auf FIRST vorhanden ist.

lg Stefan

[Tron]

Moin.

Die Seitenzahl wird im Fenster PAGE angezeigt, welches nicht auf FIRST vorhanden ist.

Ja, dann hast Du niemals eine Seitenzahl auf der ersten Seite !
gruß Jens

[Pelin2735]

Ja ich weiss, das ist mir irgendwie auch gerade aufgefallen!
Freitag schonmal an die Möglichkkeit gedacht, aber eben desswegen verworfen. Und heute morgen kams mir wie DIE Idee vor...!

Probiere dann nochmal deinen Weg aus!
gruß Stefan

[Pelin2735]

Hab jetzt die Möglichkeit gefunden, die von SAP vorgesehen ist.
Vor Basis Release 6.1 (siehe Hinweis 359009) musste man das noch über manuelles Post-Processing machen!
Unter Seitenknoten ein Fenster mit nur einen Codezeilen-Element mit folgenden Quelltext:

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. DATA: l_subrc TYPE sy-subrc.
2.  
3. PERFORM set_late_window
4.       IN PROGRAM saplstxbc
5.       USING 'PAGENO'
6.       CHANGING l_subrc.
7.  

GeSHi ©

Wobei PAGENO der Name des Fensters ist, das Nachprozessiert werden soll.
Diese Variante wird allerdings bei neueren SAP-Versionen mit einem Laufzeitfehler quittiert und darf nicht mehr eingesetzt werden.

Jetzt gibt es einfach den Fenstertyp Abschlussfenster. Diese Fensterart wird nachprozessiert und damit kann sfsy-formpages auch in der Bedingung des Fensters korrekt eingesetzt werden.

lg Stefan