Material Maintain Dark

[Kirsten3839]

Hallo!

Ich möchte gerne den FuBa Material_Maintain_Dark benutzen und zwar möchte ich einen Prognosewert in den Materialstamm eintragen. Da ich so was zum ersten Mal mache, fühle ich mich da gerade etwas überfordert. Ich habe mir die anderen Beispiele dazu angeschaut und auch soweit verstanden, glaube ich allerdings verstehe ich nicht, wo ich meinen Wert für die Prognose reinschreiben soll. In den angegeben Tabellen "amara_ueb", ... gibt es nämlich gar kein Feld für einen Prognosewert.
Kann mir da wohl jemand weiterhelfen oder hat sogar ein Besipiel? Das wäre super!!!

LG, queen

[Tron]

Moin,
nimm doch den BAPI - Funktionsbaustein BAPI_MATERIAL_SAVEDATA. Dieser ist für den Kunden freigegeben und gut dokumentiert.

gruß Tron

[Mehmet1061]

Oder für den Fall, das du ein RETAIL-System hast:
BAPI_MATERIAL_MAINTAINDATA_RT

[Ilja583]

Hallo queen,

wenn du die BAPIs nicht verwenden willst sondern den MATERIAL_MAINTAIN_DARK
( obwohl er nicht freigegeben aber trotzdem gut dokumentiert ist und letztlich sowieso nach ein paar Zeilen Umschaufeln von Variablen auch von den BAPIs gerufen wird
oder
weil dein System so alt ist, dass es zwar den MATERIAL_MAINTAIN_DARK aber nicht die BAPIs gibt ( z.B. Rel. 4.5)
oder
weil die Feldnamen in den BAPIs immer anders sind als die in den Tabellen und man jedesmal suchen muss wie sie denn im BAPI heißen und man dazu einfach zu faul ist):

Die Prognosedaten gibst du in der Tabelle AMPOP mit.

[Kirsten3839]

Hallo!

Danke für die Antworten.
Auch den BAPI Material_SaveData habe ich schon ausprobiert. Aber wo trage ich da meinen Prognosewert ein, bzw. übergebe ihn mit? Ich bin ein ziemlicher Anfänger auf dem Gebiet und stelle mich deswegen bestimmt nicht immer sehr geschickt an.

Ich packe mal meinen Code diesbzgl. mit rein:
Das ist der BAPI und ich habe einen Wert für die Prognose in der Tabelle gt_rmcp2, die ich mir im Programm vorher zusammenstelle. In der ALV GRid Ausgabe klappt das auch prima. Nur welchen TABLE muss ich unten angeben, damit er meinen Prognosewert erkennt und in den Materialstamm schreibt? So geht es jedenfalls leider nicht


FORM material USING ls_rmcp2 like gs_rmcp2.
CALL FUNCTION 'BAPI_MATERIAL_SAVEDATA'
EXPORTING
headdata = ls_rmcp2-matnr
* CLIENTDATA =
* CLIENTDATAX =
* PLANTDATA =
* PLANTDATAX =
FORECASTPARAMETERS = 'X'
FORECASTPARAMETERSX = 'X'
* PLANNINGDATA =
* PLANNINGDATAX =
* STORAGELOCATIONDATA =
* STORAGELOCATIONDATAX =
* VALUATIONDATA =
* VALUATIONDATAX =
* WAREHOUSENUMBERDATA =
* WAREHOUSENUMBERDATAX =
* SALESDATA =
* SALESDATAX =
* STORAGETYPEDATA =
* STORAGETYPEDATAX =
* FLAG_ONLINE = ' '
* FLAG_CAD_CALL = ' '
* NO_DEQUEUE = ' '
* NO_ROLLBACK_WORK = ' '
* IMPORTING
* RETURN =
* TABLES
* MATERIALDESCRIPTION =
* UNITSOFMEASURE =
* UNITSOFMEASUREX =
* INTERNATIONALARTNOS =
* MATERIALLONGTEXT =
* TAXCLASSIFICATIONS =
* RETURNMESSAGES =
* PRTDATA =
* PRTDATAX =
EXTENSIONIN = gt_rmcp2
* EXTENSIONINX =
* NFMCHARGEWEIGHTS =
* NFMCHARGEWEIGHTSX =
* NFMSTRUCTURALWEIGHTS =
* NFMSTRUCTURALWEIGHTSX =
.
ENDFORM. "Material


Danke und liebe Grüße, queen!

[Patricia2728]

Das würde mich auch interessieren:
Kann man im BAPI_MATERIAL_SAVEDATA den Prognosewert überhaupt mitgeben????
Soweit ich das momentan überblicken kann gibt es in der Struktur Forecastparameters im BAPI gar kein Feld für den Prognosewert.

Ich habe hier noch einen Baustein gefunden:
MPR1_SAVE_FORECAST_VALUES

Leider ist mir die Handhabung noch nicht ganz schlüssig ....

LittleJohn

[Tron]

Moin,
so wie ich das sehe, dienen die Prognosewerte u.a. dazu, einen Sicherheitsbestand zu haben und werden aus dem Prognoseprofil abgeleitet.
http://help.sap.com/saphelp_40b/helpdat ... ontent.htm
Die Eingabe ist meiner Meinung nach nur zu Korrekturzwecken erforderlich ?
Beispiel Materialstammpflege:

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. REPORT  ztest31                                                     .
2.  
3. DATA headdata   LIKE   bapimathead.
4. DATA return   LIKE   bapiret2.
5.  
6. DATA salesdata LIKE   bapi_mvke.
7. DATA salesdatax LIKE   bapi_mvkex.
8. DATA plantdata   LIKE   bapi_marc.
9. DATA plantdatax   LIKE   bapi_marcx.
10. DATA storagelocationdata   LIKE   bapi_mard.
11. DATA storagelocationdatax   LIKE   bapi_mardx.
12. DATA valuationdata  LIKE bapi_mbew.
13. DATA valuationdatax LIKE bapi_mbewx.
14. DATA clientdata TYPE bapi_mara.
15. DATA clientdatax TYPE bapi_marax.
16. DATA forecastparameters TYPE bapi_mpop.
17. DATA forecastparametersx TYPE bapi_mpopx.
18.  
19. DATA taxclassifications TYPE TABLE OF bapi_mlan WITH HEADER LINE.
20. DATA materiallongtext TYPE TABLE OF bapi_mltx WITH HEADER LINE.
21. DATA materialdescr TYPE TABLE OF bapi_makt WITH HEADER LINE.
22.  
23. DATA unitsofmeasure   LIKE   bapi_marm.
24. DATA unitsofmeasurex   LIKE   bapi_marmx.
25. DATA internationalartnos   LIKE   bapi_mean.
26. DATA returnmessages   LIKE   bapi_matreturn2 OCCURS 0.
27. DATA prtdata   LIKE   bapi_mfhm.
28. DATA prtdatax   LIKE   bapi_mfhmx.
29. DATA extensionin   LIKE   bapiparex.
30. DATA extensioninx   LIKE   bapiparexx.
31.  
32. DATA tname TYPE tdobname.
33. DATA:  e_rol_return           LIKE bapiret2.
34. DATA:  e_com_return           LIKE bapiret2.
35.  
36. PARAMETERS: material TYPE mara-matnr DEFAULT '000000000000001002'.
37.  
38. PERFORM xtendmat.
39.  
40. RETURN.
41.  
42. *&--------------------------------------------------------------------*
43. *&      Form  Xtendmat
44. *&--------------------------------------------------------------------*
45. *       text
46. *---------------------------------------------------------------------*
47. FORM xtendmat.
48.  
49.  
50.  
51. * KOPF Daten (Sichten) ************************************************
52.   headdata-material = material.
53.   headdata-matl_type = 'HAWA'.
54.   headdata-ind_sector ='M'.
55.   headdata-sales_view = 'X'.
56.   headdata-mrp_view = 'X'.
57.   headdata-storage_view = 'X'.
58.   headdata-account_view  = 'X'.
59.   headdata-purchase_view = 'X'.
60.   headdata-quality_view = 'X'.
61.  
62. * Prognosedaten *****************************************************
63. forecastparameters-PLANT = '0050'.
64.  
65. forecastparametersx-PLANT = '0050'.
66. * MARA Basisdaten *****************************************************
67.   clientdata-base_uom = 'ST'.
68.   clientdata-base_uom_iso = 'ST'.
69. *CLIENTDATA-PO_UNIT
70. *CLIENTDATA-PO_UNIT_ISO
71.   clientdata-matl_group = '01'.
72.  
73.  
74.  
75.   clientdatax-base_uom = 'X'.
76.   clientdatax-base_uom_iso = 'X'.
77.   clientdatax-matl_group = 'X'.
78. * Verkaufsdaten *******************************************************
79.   salesdata-sales_org = '0001'.
80.   salesdata-distr_chan = '01'.
81.   salesdata-delyg_plnt = '0050'.
82.   salesdata-item_cat = 'NORM'.
83.   salesdata-matl_grp_4 = 'E10'.
84.   salesdata-matl_stats = '1'.  " Statistikgruppe Material
85.  
86.   salesdatax-sales_org = '0001'.
87.   salesdatax-distr_chan = '01'.
88.   salesdatax-delyg_plnt = 'X'.
89.   salesdatax-item_cat = 'X'.
90.   salesdatax-matl_grp_4 = 'X'.
91.   salesdatax-matl_stats = 'X'. "Statistikgruppe Material
92.  
93. * Werksdaten *********************************************************
94.   plantdata-plant = '0050'.      " Werk
95.   plantdata-iss_st_loc = '0050'. " Lagerort
96.   plantdata-sloc_exprc = '0050'." Vorschlagslagerort f Fremdbeschaffung
97.   plantdata-mrp_type = 'ND'.     " Dispositionsmerkmal
98.   plantdata-pur_group = '001'.   " EK gruppe
99.   plantdata-loadinggrp = '0001'. " Ladegruppe
100.   plantdata-sourcelist = space.  " Kennzeichen Orderbuchpflicht
101.   plantdata-auto_p_ord = space.  " Kz: Automatische Bestellung erlaubt
102.   plantdata-plnd_delry = '10'.   " Planlieferzeit
103.   plantdata-profit_ctr = 'SAM'.  "Profit Center
104.  
105.   plantdatax-plant = '0050'.     " Werk
106.   plantdatax-iss_st_loc = 'X'.   " Lagerort
107.   plantdatax-sloc_exprc = 'X'.   " Vorschlagslort für Fremdbeschaffung
108.   plantdatax-mrp_type = 'X'.     " Dispositionsmerkmal
109.   plantdatax-pur_group = 'X'.    " EK gruppe
110.   plantdatax-loadinggrp = 'X'.   " Ladegruppe
111.   plantdatax-sourcelist = 'X'.  " Kennzeichen Orderbuchpflicht
112.   plantdatax-auto_p_ord = 'X'.  " Kz: Automatische Bestellung erlaubt
113.   plantdatax-plnd_delry = 'X'.   " Planlieferzeit
114.   plantdatax-profit_ctr = 'X'.   "Profit Center
115.  
116. * Lagerort ***********************************************************
117.   storagelocationdata-plant = '0050'.
118.   storagelocationdata-stge_loc = '0050'.
119.  
120.   storagelocationdatax-plant =    '0050'.
121.   storagelocationdatax-stge_loc = '0050'.
122.  
123. * Bewertungsdaten ****************************************************
124.   valuationdata-val_area = '0050'. "Bewertungskreis
125.   valuationdata-price_ctrl = 'V'.  "Preissteuerungskennzeichen
126. *VALUATIONDATA-STD_PRICE
127.   valuationdata-val_class = '3040'.
128.  
129.   valuationdatax-val_area = '0050'. "Bewertungskreis
130.   valuationdatax-price_ctrl = 'X'.  "Preissteuerungskennzeichen
131. *VALUATIONDATA-STD_PRICE
132.   valuationdatax-val_class = 'X'.
133.  
134. *** TABELLEN >
135. * Steuerklassifikation MLAN ******************************************
136.   taxclassifications-depcountry = 'DE'.
137.   taxclassifications-tax_type_1 = 'MWST'.
138.   taxclassifications-taxclass_1 = '1'.
139.   taxclassifications-tax_ind = space.
140.   APPEND taxclassifications.
141.  
142. * Vertriebslangtext
143. *000000000271132151 0001 01
144.   CONCATENATE material '000101' INTO tname.
145.   materiallongtext-text_name = tname.
146.   materiallongtext-applobject = 'MVKE'.
147.   materiallongtext-text_id = '0001'.
148.   materiallongtext-langu = 'D'.
149.   materiallongtext-format_col = '*'.
150.   materiallongtext-text_line = 'Hier nun der Langtext'.
151.   APPEND materiallongtext.
152.  
153. * Materialkurztext(MAKT)
154.   materialdescr-langu = sy-langu.
155. *LANGU_ISO
156.   materialdescr-matl_desc = 'Abstinence in a material world'.
157. *materialdescr-DEL_FLAG =
158.   APPEND materialdescr.
159.  
160.   CALL FUNCTION 'BAPI_MATERIAL_SAVEDATA'
161.     EXPORTING
162.      headdata                   = headdata
163.     clientdata                 = clientdata
164.     clientdatax                = clientdatax
165.      plantdata                  = plantdata
166.      plantdatax                 = plantdatax
167. *   FORECASTPARAMETERS         =
168. *   FORECASTPARAMETERSX        =
169. *   PLANNINGDATA               =
170. *   PLANNINGDATAX              =
171.      storagelocationdata        = storagelocationdata
172.      storagelocationdatax       = storagelocationdatax
173.      valuationdata              = valuationdata
174.      valuationdatax             = valuationdatax
175. *   WAREHOUSENUMBERDATA        =
176. *   WAREHOUSENUMBERDATAX       =
177.      salesdata                  = salesdata
178.      salesdatax                 = salesdatax
179. *   STORAGETYPEDATA            =
180. *   STORAGETYPEDATAX           =
181. *   FLAG_ONLINE                = ' '
182. *   FLAG_CAD_CALL              = ' '
183. *   NO_DEQUEUE                 = ' '
184.    IMPORTING
185.      return                     = return
186.    TABLES
187.       materialdescription        = materialdescr[]
188. *   UNITSOFMEASURE             =
189. *   UNITSOFMEASUREX            =
190. *   INTERNATIONALARTNOS        =
191.       materiallongtext           = materiallongtext[]
192.       taxclassifications         = taxclassifications[]
193.       returnmessages             = returnmessages[]
194. *   PRTDATA                    =
195. *   PRTDATAX                   =
196. *   EXTENSIONIN                =
197. *   EXTENSIONINX               =
198.             .
199.  
200.   IF return-type = 'E' OR return-type = 'A'.
201.     WRITE:/ 'Fehler Bapi'.
202.     WRITE:/ 'Type       ', return-type.
203.     WRITE:/ 'ID         ', return-id.
204.     WRITE:/ 'NUMBER     ', return-number.
205.     WRITE:/ return-message.
206.     WRITE:/ '-----------------------------------------'.
207.   ENDIF.
208.  
209.   CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
210.     EXPORTING
211.       wait   = 'X'
212.     IMPORTING
213.       return = e_com_return.
214.  
215.   IF e_com_return-type NE space.
216.  
217.     CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'
218.       IMPORTING
219.         return = e_rol_return.
220.     WRITE:/ 'Rollback', e_rol_return-type.
221.   ENDIF.
222.  
223. ENDFORM.                    "Xtendmat

GeSHi ©

Das Beispiel von queen kann nicht funktionieren.

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. REPORT  ZTEST26                                                     .
2. *MPR1_SAVE_FORECAST_VALUES
3.  
4. type-pools MPR1T.
5.  
6. data ART type table of MPR1T_S_ARTICLES with header line.
7. *    WERKS          LIKE MAPR-WERKS,
8. *    MATNR          LIKE MAPR-MATNR,
9. *    MEINS          LIKE MARA-MEINS,
10. *    MINBE          LIKE MARC-MINBE,Meldebestand
11. *    EISBE          LIKE MARC-EISBE,Sicherheitsbestand
12.  
13. art-werks = '0050'.
14. art-matnr = '000000000000000016'.
15. art-meins = 'ST'.
16. art-minbe = '7'.
17. art-eisbe = '5'.
18. append art.
19.  
20. data fv type table of MPR1T_S_FORECAST_VALUES with header line.
21. *    WERKS          LIKE MAPR-WERKS,
22. *    MATNR          LIKE MAPR-MATNR,
23. *    PERKZ          LIKE MAPR-PERKZ, Periodenkennzeichen
24. *    PERIV          LIKE MAPR-PERIV, Geschäftsjahresvariante
25. *    ERTAG          LIKE PROW-ERTAG, Erster Tag der Periode, auf den
26. *                                    sich die Werte beziehen
27. *    PRWRT          LIKE PROW-PRWRT, Prognosewert
28. *    KOPRW          LIKE PROW-KOPRW, Korrekturwert für Prognosewert
29. *    MEINS          LIKE MARA-MEINS, Mengeneinheit
30. fv-werks = '0050'.
31. fv-matnr = '000000000000000016'.
32. fv-meins = 'ST'.
33. fv-PERIV = '10'.
34. fv-ERTAG = '20100201'.
35. fv-KOPRW = '13'.
36. append fv.
37.  
38.  
39. data mes type table of MPR1T_S_MESSAGES  with header line.
40.  
41. CALL FUNCTION 'MPR1_SAVE_FORECAST_VALUES'
42.   EXPORTING
43.     i_commit                = 'X'
44.   tables
45.     t_articles              = art
46.     t_forecast_values       = fv
47.     t_messages              = mes.
48.  

GeSHi ©

Einige Werte müssten noch von Dir angepasst werden.
gruß Tron