Import Transporte ins Zielsystem durch anderen User

[Yannik3028]

Hallo zusammen,

bisher konnten bei uns jeder seine Transporte selbst ins Produktivsystem "transportieren", wenn vom User die Freigabe kam.

Zukünftig soll das nicht mehr möglich sein, d.h. mein Kollege muss meine und ich muss seine Transporte ins Produktivsystem transportieren.
Kann man das systemseitig lösen ? Also der Import ins Prod.system darf nur erfolgen, wenn Inhaber vom TA <> User, der importieren will.

Danke
Matthias

[Tron]

Hallo,
wir haben das Badi IF_EX_CTS_REQUEST_CHECK Zeitpunkt:IF_EX_CTS_REQUEST_CHECK~CHECK_BEFORE_RELEASE ausprogrammiert. Hier kann man eine Transportfreigabe verhindern, nach Regeln die man selbst definieren kann. Sei es eine zwingend erforderliche Ticketnummer im Kurztext oder ein erzwungener Personenkreis.
(kann man lokal anlegen, da man die implementation ja nur im DEV-System braucht)
Wir haben für Importe nur die Möglichkeit, auszuwerten WER den Importknopf gedrückt hat, das eigentliche Importieren können wir eigentlich nicht verhindern

gruß Tron

[Bianka187]

hallo Tron,

bei diesem BAPI habe ich jetzt die Aufgabe zu prüfen ob zu dem Auftrag ein Langtext eingegeben wurde. Ihr habt nicht zufällig eine solche Abfrage mit programmiert?

Was müsste ich eigentlich durch die Methode auslösen, damit eine Freigabe abgebrochen wird?

[Tron]

Moin Alex,
(issn BADI = SE19)




mit dem "Raise Cancel" wird die Freigabe abgelehnt.

Du müsstest, je nach Anforderung, noch auswerten, ob Du nur den Auftrag, oder Auftrag und Aufgabe prüfen/sperren willst. Wo sind die Dokumentationen zu finden ?
In etwa so:

Das DIALOG Flag bestimmt, ob Du im Hintergrund (= Space) freigibst.

Die Dokumentation eines TR-Auftrags kann mit TR_DOCU_INTERFACE
gelesen werden.
Beispiel

Code: [Select all] [Expand/Collapse] [Download] (Untitled.txt)

1. METHOD if_ex_cts_request_check~check_before_release.
2.   DATA lv_text(35).
3.   DATA lv_strkorr TYPE e070-strkorr.
4.   DATA lt_line TYPE TABLE OF tline.
5.  
6. *  check sy-mandt ne '000'. "siehe unten
7.  
8.   SELECT SINGLE strkorr FROM e070 INTO lv_strkorr WHERE trkorr = request.
9.  
10. * Prüfe auf AUFTRAG
11.   IF lv_strkorr IS INITIAL.
12.  
13. * komm Pfiffi .. such die Doku...
14.     CALL FUNCTION 'TR_DOCU_INTERFACE'
15.       EXPORTING
16.         iv_object                 = request
17.         iv_action                 = 'R'
18.         iv_modify_appending       = 'X'
19.       TABLES
20.         tt_line                   = lt_line
21.       EXCEPTIONS
22.         ret_code                  = 1
23.         iv_object_value_unallowed = 2
24.         order_not_exist           = 3
25.         order_already_released    = 4
26.         no_authority              = 5
27.         user_not_owner            = 6
28.         locked_by_other           = 7
29.         OTHERS                    = 8.
30.  
31.     IF sy-subrc <> 0.
32. * Implement suitable error handling here
33.     ENDIF.
34.  
35. * Doku muss vorhanden sein
36.     IF  lt_line[] IS INITIAL.
37.  
38. * bei Hintergrundverarbeitung kein Popup
39.       IF NOT dialog IS INITIAL.
40.  
41.         CONCATENATE 'Freigabe:'(001) request INTO lv_text.
42.         CALL FUNCTION 'POPUP_TO_INFORM'
43.           EXPORTING
44.             titel = lv_text
45.             txt1  = '@8O@ Freigabe wurde abgelehnt :'(002)
46.             txt2  = 'Keine Doku .. keine Freigabe !'(003).
47.       ENDIF.
48.  
49. * Freigabe verhindern
50.       RAISE cancel.
51.  
52.     ENDIF."LT_LINE[] IS INITIAL
53.  
54.   ENDIF."STRKORR NE INITIAL
55.  
56.  
57. ENDMETHOD.

GeSHi ©

gruß Jens
Ps.: Das "Ganze" ist Mandantenübergreifend !

(Was in meinem Fall mal dazu führte, daß die Basis (externer Anbieter im Mandant 000) von meinem Freigabemechanismus nichts wusste und einen CALL bei SAP aufgemacht hat.
Das Popup sah wohl einfach zu professionell aus.)

Vielleicht ein bisschen so:

[Bianka187]

hallo Tron,

na das nenne ich eine ausführliche Antwort! Vielen Dank dafür, es funktioniert nun alles wie wir uns das vorstellen.

Seid ihr nach diesem Vorfall mit der Basis noch Freunde?

[Tron]

Nun..,
Wir haben zwischenzeitlich den Anbieter gewechselt. Wir haben 3 - Jahresverträge, dann entscheidet wohl der Preis/Leistung (und nicht ein Popup). Aber gut dass Du es erwähnst, vielleicht kennt die "Neue" Basis-Truppe mein Popup noch nicht, so daß ...
gruß Jens